***************************************;
* f=prog_mbquest2.sas                 *;
*                                     *;
* SAS code to answer the research-    *;
* oriented questions, using the       *;
* simulated MB Health data in a       *;
* program that creates the necessary  *;
* code in one data step.              *;
* This assumes the temporary SAS      *;
* set "test" has been created.        *;
*                                     *;
* NOTE: the "formchar" option in the  *;
* PROC FREQ statements were required  *;
* here to enable Web display of       *;
* tables - it is not normally needed. *;
***************************************;

%include 'c:\winnt\profiles\Ruth\personal\My SAS files\sasmanual\formats\fmts95.sas';


data final;
  set test;

****---Question 1-----****;

  lensop = ('13  '<=op01<='1399');  /* Flag eye operations */

  *Another way of flagging the eye operations: *;

  lensop2=substr(op01,1,2)='13';

*(Question 2 does not need new variable code)*;

****---Question 3----****;

  if '820  '<=diag01<='82099' then hipfx=1;
  else if '820  '<=diag02<='82099' then hipfx=1;
  else hipfx=0;

  *(Note that substring could be used instead.
    Also note that a DO loop, with an ARRAY,
    can be used for performing repetitive tasks
    such as the above and should be used when
    many fields need to be processed.)

*(Question 4 does not need new variable code)*;

****---Question 5-----****;

deathall= (.<deathsep<9999);
death90 = (.<deathsep<=90);
readm90 = (.<daystor<=90);

run;

title1 'Research-Oriented Questions Using Simulated MB Health Data';

proc print data=final (obs=40);
  var op01 lensop lensop2;
title2 'Question 1 - Check new variables';
run;

proc sort data=final;
  by lensop;
run;

proc means;
  var age;
  by lensop;
title2 'Question 1 - mean age for lens vs no lens operation';
run;

proc freq formchar (1,2,7) = '|-+';
  tables diag01 * diag02 /list missing;
where hipfx=1;
title2 'Question 2 - Check new variable';
run;

proc freq formchar (1,2,7) = '|-+';
  tables incdr * typehsp;
format typehsp $typehl.  incdr $incdrl.;
title2 'Question 2 - income by type of hospital';
run;

proc freq formchar (1,2,7) = '|-+';
  tables tranadm trandis;
  where hipfx=1;
  format tranadm $trnadml. trandis $trndisl.;
title2 'Question 3 - Hip fractures by transfers';
run;

proc freq formchar (1,2,7) = '|-+';
  tables icd17brk * (charyes gender);
  format icd17brk $icd17l. charyes $charl. gender $genderl.;
title2 'Question 4 - 17 ICD-9-CM categories by CCI, by Gender';
run;

proc freq formchar (1,2,7) = '|-+';
  tables deathsep * death90 * deathall /list missing;
  tables deathall * death90 /list missing;
title2 'Question 5 - Check new variables';
run;

proc freq formchar (1,2,7) = '|-+';
  tables deathall death90;
title2 'Question 5: All deaths and 90-day mortality';
run;